home *** CD-ROM | disk | FTP | other *** search
/ SGI Hot Mix 17 / Hot Mix 17.iso / HM17_SGI / research / lib / slicer.pro < prev    next >
Text File  |  1997-07-08  |  54KB  |  1,718 lines
  1. ; $Id: slicer.pro,v 1.25 1997/02/13 00:00:04 ali Exp $
  2. ;
  3. ; Copyright (c) 1991-1997, Research Systems, Inc.  All rights reserved.
  4. ;       Unauthorized reproduction prohibited.
  5.  
  6. ;
  7. ; Conventions:
  8. ; Faces = faces of cube.  Numbered 0 to 5:
  9. ;        0 = X = c0[0]  (Corner 0)
  10. ;        1 = Y = c0[1]
  11. ;        2 = Z = c0[2]
  12. ;        3 = X = c1[0]  (Corner 1)
  13. ;        4 = Y = c1[1]
  14. ;        5 = Z = c1[2]
  15. ; Orientations:
  16. ;    6 = reset to default.
  17. ;    0 = xy exchange, 1 = xz exchange, 2 = yz exchange.
  18. ;    3 = x reverse, 4 = y reverse, 5 = z reverse.
  19. ; Vertex indices:    Faces
  20. ;    0    0,0,0   0,1,2
  21. ;    1    N,0,0    1,2,3
  22. ;    2    0,N,0    0,2,4
  23. ;    3    N,N,0    2,3,4
  24. ;    4    0,0,N    0,1,5
  25. ;    5    N,0,N    1,3,5
  26. ;    6    0,N,N    0,4,5
  27. ;    7    N,N,N    3,4,5
  28. ;
  29. ; Edge Index    Vertex Indices
  30. ;    0    0-1
  31. ;    1    1-2
  32. ;    2    2-3
  33. ;    3    3-1
  34. ;    4    0-4
  35. ;    5    1-5
  36. ;    6    2-6
  37. ;    7    3-7
  38. ;    8    4-5
  39. ;    9    5-6
  40. ;    10    6-7
  41. ;    11    7-4
  42. ;
  43. ; Modes:
  44. ;    0 = Slices
  45. ;    1 = Cube
  46. ;    2 = Cut
  47. ;    3 = Isosurface
  48. ;    4 = Probe
  49. ;    5 = rotations
  50.  
  51.  
  52. function p_inside_poly, polyv, p
  53. ;    polyv = [2,n] array of polygon vertices, either clockwise or
  54. ;        counter-clockwise order.  Polygon must be convex.
  55. ;    p = (2) point coordinates.
  56. ;    return 0 if point is outside polygon, 1 if inside.
  57. ;
  58. x = float(p[0])
  59. y = float(p[1])
  60. np = n_elements(polyv)/2        ;# of vertices
  61. x1 = polyv[0,np-1]        ;Start at last point
  62. y1 = polyv[1,np-1]
  63.  
  64. pos = -1
  65. for i=0,np-1 do BEGIN
  66.     x2 = polyv[0,i]
  67.     y2 = polyv[1,i]
  68.     k = (x*(y1-y2) + y * (x2-x1) + x1*y2-y1*x2)  ;Side of line point is on
  69.     if k eq 0 THEN BEGIN    ;On line?
  70.         if (y lt (y1< y2)) or (y gt (y1 > y2)) or  $  ;Check more
  71.         (x lt (x1 < x2)) or (x gt (x1 > x2)) THEN return,0
  72.     ENDIF ELSE BEGIN        ;Not on line
  73.         k = k gt 0        ;1 if on right side
  74.         if pos lt 0 then pos = k
  75.         if pos ne k THEN return,0
  76.     ENDELSE
  77.     x1=x2        ;Previous vertex
  78.     y1=y2
  79.     ENDFOR
  80. return,1
  81. end
  82.  
  83.  
  84.  
  85. Function p_inverse, x, y, z
  86. ;
  87. ; Given one or more screen coordinates, and their Z-buffer values
  88. ; return the object space (volume subscript) coordinates of that point.
  89. ;
  90. ;  On input: x, y = scalars or vectors containing the device coordinate(s)
  91. ;    z = zbuffer value(s) at [x,y]
  92. ;  Result: [3,n] vector of object space (volume) coordinates.
  93.  
  94. COMMON slicer_common, dims, sl, z_last, zb_last, mode, fixed
  95.  
  96. ; Method:
  97. ; - Convert screen coords to normalized coords.
  98. ; - Multiply by inverse of 3D transformation.
  99. ; - Scale back to data coordinates.
  100. ;
  101. ; ******* Old way *************
  102. ; ones = replicate(1, n_elements(x))
  103. ; v = [[x /  float(!d.x_size)], $        ;To normalized coordinates.
  104. ;      [y / float(!d.y_size)], $
  105. ;      [z/65530.+0.5], $
  106. ;      [ones]]
  107. ; v = ((temporary(v) # sl.pt_inverse) - (ones # [!x.s[0], !y.s[0], !z.s[0]])) / $
  108. ;     (ones # [ !x.s[1], !y.s[1], !z.s[1]])
  109. ;
  110. ; **************************
  111. ; The new way folds everything into the matrix multiplication operation
  112. ; and is much faster, although its very, very, obtuse.
  113. ; 
  114.  
  115. ; Apply to normalized conversion to inverse matrix.
  116. q = sl.pt_inverse * (1./[!d.x_size, !d.y_size, 65530., 1.]  # replicate(1.,4))
  117.  
  118. s = 1./[!x.s[1], !y.s[1], !z.s[1], 1.0]   ;To data coord scale factors
  119. t = [!x.s[0], !y.s[0], !z.s[0], 0.0]
  120. q = q * transpose(s # replicate(1.,4)) ; Mult inv matrix by 1/![xyz].s[1]
  121. q[3,0] = q[3,*] - transpose(t * s)    ;Add in t*s.
  122. return, ([[x],[y],[z+32765L], [replicate(1L, n_elements(x))]] # q)[*,0:2]
  123. end
  124.  
  125.  
  126.  
  127. Function slicer_plane_int, dummy
  128. ; Return the intersections of the plane with the volume cube.
  129. ; V[3,12] = intersections of plane with the 12 edges.
  130. ; Flags[12] = 1 if there is an intersection at that edge.
  131. COMMON slicer_common, dims, sl, z_last, zb_last, mode, fixed
  132.  
  133. Jn = sl.orthop[0:2]            ;Plane eqn
  134. Jd = sl.orthop[3]
  135.  
  136. v = fltarr(3,12)
  137. k = 0
  138.  
  139. for i=0,11 do begin            ;Faces
  140.     p0 = sl.p0[*,sl.edges[0,i]]        ;Beginning of edge
  141.     p1 = sl.p0[*,sl.edges[1,i]]        ;End of edge
  142.     lv = p1-p0
  143.     t = total(lv * Jn)
  144.     if t ne 0 then begin
  145.     t = -(jd + total(p0 * Jn)) / t
  146.     p = p0 + t * lv            ;Point of intersection
  147.     d = min((p - p0) * (p1-p))
  148.     if d ge 0.0 then begin        ;Within edge?
  149.         v[0,k] = p            ;Yes, save intersection
  150.         k = k + 1
  151.         endif          
  152.     endif                ;T ne 0
  153.     endfor                    ;i
  154.  
  155. ; Sort into order:
  156. d = max(abs(Jn), m)            ;Largest plane coeff = what we ignore
  157. u = v[[m+1, m+2] mod 3, 0:k-1]        ;Get other 2 coords
  158. a = fltarr(k)                ;Angle measure
  159. d = min(u[1,*], dmin)            ;Get lowest point
  160. u_dx = u[0,*]-u[0,dmin]
  161. u_dy = u[1,*]-u[1,dmin]
  162. zero_ind = Where((u_dx EQ 0.0) AND (u_dy EQ 0.0))
  163. if (zero_ind[0] GE 0L) THEN u_dx[zero_ind] = 1.0
  164. a=atan(u_dy, u_dx)
  165. zero_ind=0 & u_dx=0 & u_dy=0
  166. a[dmin] = -100.                ;Anchor = first
  167. n = sort(a)                ;Go around anchor point & back
  168. return, v[*, [n, n[0]]]
  169. end
  170.  
  171.  
  172.  
  173.  
  174. PRO SLICER_PLAYBACK, FILE = file, Commands
  175. ; Play back a journal.  Commands are either in the designated file
  176. ; or in the string array Commands".
  177. COMMON slicer_common, dims, sl, z_last, zb_last, mode, fixed
  178. COMMON slicer_common1, old_slice, d0, z0, az, el
  179.  
  180. if n_elements(file) gt 0 THEN BEGIN    ;Read from file
  181.     OPENR, unit, /GET_LUN, file, ERROR = i
  182.     if i ne 0 then begin    ;OK?
  183.         widget_control, sl.file_text[1], set_value = !ERR_STRING
  184.         return
  185.         ENDIF
  186.     commands = strarr(100)        ;Read up to 100 lines
  187.     i = 0
  188.     a = ''
  189.     while not eof(unit) do begin
  190.         readf, unit, a
  191.         commands[i] = a
  192.         i = i + 1
  193.         endwhile
  194.     ncommands = i
  195.     free_lun, unit
  196. ENDIF ELSE ncommands = n_elements(commands)
  197.  
  198. IF mode ne 7 THEN BEGIN            ;Not our mode?
  199.     if sl.mode_bases[mode] ne 0 THEN $  ;Remove panel if mapped
  200.         WIDGET_CONTROL, sl.mode_bases[mode], MAP=0
  201.     mode = 7            ;New mode = ours
  202.     WIDGET_CONTROL, sl.mode_bases[mode], MAP=1
  203.     ENDIF
  204.  
  205. pars = fltarr(10)
  206.  
  207. for i=0, ncommands-1 do begin        ;Each command
  208.     s = strtrim(strcompress(commands[i]))    ;Parse it, extracting fields
  209.     j = 0
  210.     m = 0
  211.     while j lt strlen(s) do begin    ;While string left
  212.         k = strpos(s, ' ', j)    ;Find next blank
  213.         if k le 0 then k = strlen(s)  ;if none, go to end of string
  214.         if j eq 0 then cmd = strmid(s,0,k) $
  215.         else begin pars[m] = strmid(s,j,k) & m=m+1 & endelse
  216.         j = k+1
  217.         endwhile
  218.     WIDGET_CONTROL, sl.file_text[1], SET_VALUE = strmid(s,0,32)
  219.     case strupcase(cmd) of        ;Interpret commands.....
  220. "UNDO": slicer_undo
  221. "ORI":  BEGIN    ;AXIS(3), AXIS_REVERSE(3), ROTATIONS(2)
  222.     sl.axex = pars[0:2]
  223.     sl.axrev = pars[3:5]
  224.     sl.rotation = pars[6:7]
  225.     for j=0,1 do WIDGET_CONTROL, sl.rslide[j], SET_VALUE = sl.rotation[j]
  226.     WIDGET_CONTROL, sl.rslide[2], SET_VALUE=string(pars[8])  ;Aspect
  227.     SLICER_ORIENTATION
  228.     ENDCASE
  229. "TRANS": BEGIN   ;On/Off Threshold(%)
  230.     sl.trans = pars[0]
  231.     if sl.trans eq 0 then pars[1] = 100
  232.     sl.threshold = pars[1] /100. * sl.nc3
  233.     WIDGET_CONTROL, sl.threshold_slider, SET_VALUE = pars[1]
  234.     ENDCASE
  235. "SLICE": BEGIN      ;Axis, slice_value, interp, expose, 0 for orthogonal
  236.         ;Azimuth, Elev, interp, expose, 1, x0, y0, z0 for oblique
  237.     sl.interp = pars[2]
  238.     sl.expose = pars[3]
  239.     if pars[4] eq 0 then begin    ;Orthogonal slices?
  240.         WIDGET_CONTROL, sl.draw_butt[sl.expose], /SET_BUTTON
  241.         SLICER_DRAW, pars[0], pars[1]
  242.     ENDIF ELSE BEGIN        ;Oblique slice
  243.         az = pars[0]
  244.         el = pars[1]
  245.         s = sin(el * !DTOR)
  246.         sl.orthop[0] = sin(-az * !dtor) * s
  247.         sl.orthop[1] = cos(-az * !dtor) * s
  248.         sl.orthop[2] = cos(el * !dtor)
  249.         z0 = pars[5:7]
  250.         sl.orthop[3] = -total(sl.orthop * z0)
  251.         d0 = slicer_plane_int()
  252.         slicer_oblique
  253.     ENDELSE
  254.     ENDCASE
  255. "COLOR": BEGIN     ;Table_num (-1 = present), low, high, shading
  256.     sl.stretch = pars[1:2]
  257.     sl.shading = pars[3]/100.
  258.     for j=0,2 do WIDGET_CONTROL, sl.cslide[j], SET_VALUE = pars[j+1]
  259.     slicer_colors,     pars[0]
  260.     ENDCASE
  261. "ISO":  BEGIN        ;value, hi/lo
  262.     sl.isop.value = pars[0] / 100. * (sl.amax-sl.amin) + sl.amin
  263.     sl.isop.hi_lo = pars[1]
  264.     DO_ISOSURFACE
  265.     ENDCASE
  266. "ERASE":  slicer_erase
  267. "WAIT":  wait, pars[0]
  268. "CUBE": BEGIN        ;mode (1 = block, 0 = cutout), cut_ovr, interp,
  269.             ; start_coords(3), end_coords(3)
  270.     mode = pars[0]
  271.     sl.cut_ovr = pars[1]
  272.     sl.interp = pars[2]
  273.     sl.p0cube = reform(pars[3:8], 3,2)
  274.     DO_CUBE    
  275.     ENDCASE
  276.     ENDCASE
  277.   ENDFOR
  278. mode=7
  279. WIDGET_CONTROL, sl.file_text[1], SET_VALUE = 'Playback Done'
  280. end
  281.  
  282. ; Journal events if journal file is open.
  283. PRO SLICER_JOURNAL, name, params
  284. COMMON slicer_common, dims, sl, z_last, zb_last, mode, fixed
  285.  
  286. if sl.journal le 0 then return
  287. if n_elements(params) le 0 then params = 0.
  288. printf, sl.journal, name, params, format='(A, 1x, 10F10.3)'
  289. end
  290.  
  291.  
  292. PRO SLICER_UNDO        ;Undo last operation
  293. COMMON slicer_common, dims, sl, z_last, zb_last, mode, fixed
  294.  
  295. SLICER_JOURNAL, "UNDO"
  296. if n_elements(zb_last) le 1 then return
  297. set_plot,'Z'
  298. tmp = tvrd(/WORDS, CHANNEL=1)  ;Read depth buffer & swap
  299. tv, zb_last, CHANNEL=1, /WORDS
  300. zb_last = temporary(tmp)
  301. tmp = tvrd()        ;Swap them
  302. tv, z_last
  303. slicer_show, z_last
  304. z_last = tmp
  305. end
  306.  
  307.  
  308. PRO slicer_orientation, i    ;i = orientation
  309. ;  Set the New Orientation
  310. COMMON volume_data, a
  311. COMMON slicer_common, dims, sl, z_last, zb_last, mode, fixed
  312. if n_elements(i) gt 0 THEN BEGIN
  313.     if i le 2 THEN BEGIN
  314.         j = 2 * i
  315.         ll = ([0,1,0,2,1,2])[j:j+1]  ;axes to swap
  316.         t = sl.axex[ll[0]] & sl.axex[ll[0]] = sl.axex[ll[1]] & 
  317.         sl.axex[ll[1]] = t
  318.     ENDIF ELSE if i eq 6 THEN BEGIN
  319.         sl.axex = [0,1,2]        ;default transformation
  320.         sl.axrev = intarr(3)
  321.     ENDIF ELSE sl.axrev[i-3] = 1-sl.axrev[i-3]  ;reverse
  322. ENDIF        
  323.  
  324. d = [ 0., dims[0], 0., dims[1], 0., dims[2]]
  325. f = 1.0
  326. WIDGET_CONTROL, sl.rslide[2], GET_VALUE=s
  327. ON_IOERROR, bad_aspect
  328. f = (float(s))[0]
  329. if (f le 0.0) then goto, bad_aspect
  330. IF f gt 1. THEN BEGIN
  331.     x = (f-1)/2.
  332.     d[0] = [-x * dims[0], (x+1) * dims[0], -x * dims[1], (x+1) * dims[1]]
  333. ENDIF ELSE BEGIN
  334.     x = (1-f)/2
  335.     d[4] = [-x * dims[2], (x+1) * dims[2]]
  336. ENDELSE
  337. bad_aspect:
  338. SLICER_JOURNAL, "ORI", [sl.axex, sl.axrev, sl.rotation, f ]
  339.  
  340. for i=0,2 do if sl.axrev[i] THEN BEGIN    ;Swap endpoints for reversed axes
  341.     j=i*2
  342.     t = d[j] & d[j] = d[j+1] & d[j+1] = t
  343.     ENDIF
  344.  
  345. !x.type = 0        ;make sure its linear
  346. scale3, xrange=d[0:1], yrange=d[2:3], zrange=d[4:5], ax = sl.rotation[0], $
  347.     az = sl.rotation[1]
  348.  
  349. k = 1        ;current y axis
  350. if sl.axex[0] ne 0 THEN BEGIN    ;swap x?
  351.     if sl.axex[0] eq 1 THEN BEGIN &    t3d, /XYEXCH & k = 0
  352.     ENDIF ELSE t3d,/XZEXCH
  353. ENDIF
  354.  
  355. if k ne sl.axex[1] THEN t3d,/YZEXCH
  356. slicer_erase
  357. if mode le 2 THEN draw_orientation
  358. sl.pt_inverse = invert(!p.t)
  359. end
  360.  
  361.  
  362.  
  363.  
  364.  
  365. PRO slicer_oblique        ;Do an oblique slice
  366. ;    Plane eqn is in sl.orthop
  367. ;    d0 is the intersections of the plane with the edges of the volume
  368. ;        cube.
  369. COMMON volume_data, a
  370. COMMON slicer_common, dims, sl, z_last, zb_last, mode, fixed
  371. COMMON slicer_common1, old_slice, d0, z0, az, el
  372.  
  373. if n_elements(d0) le 3 then return        ;Anything?
  374.  
  375. SLICER_JOURNAL, "TRANS", [sl.trans, sl.threshold * 100. / sl.nc3]
  376. SLICER_JOURNAL, "SLICE", [az, el, sl.interp, sl.expose, 1., z0 ]
  377.  
  378. widget_control, sl.pos_text, set_value = 'Extracting Oblique Slice'
  379. set_plot,'Z'
  380. z = (z_last = tvrd())            ;save previous image & z
  381. zb = (zb_last = tvrd(CHANNEL=1, /WORDS))
  382. erase
  383. polyfill, d0, /T3D, /DATA    ;Mark the slice
  384. z1 = tvrd(CHANNEL=1, /WORDS)    ;Read depth buffer
  385.  
  386. if sl.expose then points = where((z1 lt zb_last) and (z1 ne z1[0,0])) $
  387.     else points = where(z1 gt zb_last)
  388.  
  389. if points[0] lt 0 then begin
  390.     z=z_last
  391.     zb = zb_last
  392.     goto, done
  393.     endif
  394.  
  395. widget_control, sl.pos_text, set_value = $
  396.     STRING(n_elements(points), FORMAT="(i6, ' points')")
  397.  
  398. ; Get voxel subscripts from screen coords:
  399. v = p_inverse(points mod !d.x_size, points / !d.x_size, z1[points])
  400.  
  401. ;        Either interpolate or pick nearest neighbor
  402. if sl.interp THEN v = interpolate(a, v[*,0], v[*,1], v[*,2]) $
  403.     else v = a[long(temporary(v)) # [1, dims[0], dims[0] * dims[1]]]
  404.  
  405. v = bytscl(temporary(v), max=sl.amax, min=sl.amin, top = sl.nc3-1) ;face data
  406.  
  407. if sl.trans THEN BEGIN        ;Transparency?  Remove those under thresh.
  408.     good = where(v ge sl.threshold)
  409.     v = v[good]
  410.     points = points[good]
  411.     endif
  412.  
  413. dummy = max(abs(sl.orthop[0:2]), kmax)    ;Axis with smallest variation
  414. if kmax ne 0 then z[points] = v + byte(kmax * sl.nc3)  $ ;Shade it
  415. else z[points] = v
  416.  
  417. zb[points] = z1[points]        ;Update depth buffer
  418.  
  419. done: tv, z                    ;Now show it
  420. tv, zb, /WORDS, CHANNEL=1        ;and update depth buffer
  421.  
  422. widget_control, sl.pos_text, set_value = $
  423.       STRING(z0, az, el, FORMAT="('(',3f5.1,') A=', i4, ' E=',i4)")
  424. slicer_show
  425. end
  426.  
  427.  
  428.  
  429.  
  430. PRO slicer_draw, ax, slice        ;draw a slice.
  431. ;  ax = axis, 0 for x, 1 for Y, 2 for Z. slice = plane number.
  432. COMMON volume_data, a
  433. COMMON slicer_common, dims, sl, z_last, zb_last, mode, fixed
  434.  
  435. WIDGET_CONTROL, sl.base, /HOURGLASS
  436. SLICER_JOURNAL, "TRANS", [sl.trans, sl.threshold * 100. / sl.nc3]
  437. SLICER_JOURNAL, "SLICE", [ax, slice, sl.interp, sl.expose, 0.]
  438.  
  439. set_plot,'Z'
  440. z_last = tvrd()            ;save previous image & z
  441. zb_last = tvrd(CHANNEL=1, /WORDS)
  442.  
  443. d0 = [0,0,0]
  444. d1 = dims -1
  445. d0[ax] = slice
  446. d1[ax] = slice
  447.  
  448. if sl.expose THEN erase        ;Get a clean slice
  449.                 ;extract & scale the slice
  450. offset = byte(ax*sl.nc3)    ;bias for this slice
  451. p = bytscl(a[d0[0]:d1[0], d0[1]:d1[1], d0[2]:d1[2]], $
  452.     max=sl.amax, min=sl.amin, top = sl.nc3-1)
  453.  
  454. if sl.trans THEN t = (sl.threshold > 1) + offset $  ;lower limit
  455.     ELSE t = 0
  456. if ax ne 0 THEN p = p + offset    ;add bias
  457. d1 = dims-1
  458. s = replicate(slice, 4)
  459.  
  460. case ax of
  461. 0:    polyfill, s, [0,d1[1],d1[1],0],[0,0,d1[2],d1[2]],/T3D,$
  462.         pat=reform(p, dims[1], dims[2], /OVER), $
  463.         image_coord = [0,0, d1[1],0, d1[1],d1[2], 0,d1[2]], $
  464.         image_interp= sl.interp, trans=t
  465. 1:    polyfill, [0,d1[0],d1[0],0],s,[0,0,d1[2],d1[2]],/T3D,$
  466.         pat=reform(p, dims[0], dims[2], /OVER), $
  467.         image_coord = [0,0, d1[0],0, d1[0],d1[2], 0,d1[2]], $
  468.         image_interp= sl.interp, trans=t
  469. 2:    polyfill,[0,d1[0],d1[0],0],[0,0,d1[1],d1[1]],s,/T3D,$
  470.         pat=reform(p, dims[0], dims[1], /OVER),$
  471.         image_coord = [0,0, d1[0],0, d1[0],d1[1], 0,d1[1]], $
  472.         image_interp= sl.interp, trans=t
  473.     ENDCASE
  474.  
  475. if sl.expose THEN BEGIN
  476.     z = tvrd(/WORDS, CHANNEL=1)    ;The new slice
  477.     pnts = where((z gt zb_last) + (z eq z[0,0])) ;where we display prev
  478.     if n_elements(pnts) gt 1 then begin
  479.         z[pnts] = zb_last[pnts]        ;New Z
  480.         tv, z, /WORDS, CHANNEL=1
  481.         z = tvrd()            ;New display
  482.         z[pnts] = z_last[pnts]
  483.         tv, z
  484.         ENDIF
  485.     ENDIF
  486. slicer_show
  487. end
  488.  
  489. PRO slicer_colors, table    ;load our color table
  490. ; Table = index of color table to load, -1 to retain present.
  491. ; The color palette is repeated 3 times, once for each of the possible face
  492. ; directions.  The colors indices:
  493. ;  3 * sl.nc3  = red
  494. ;  3 * sl.nc3 + 1 = green
  495. ;  3 * sl.nc3 + 2 = blue
  496. ;  3 * sl.nc3 + 3 = white
  497.  
  498. COMMON volume_data, a
  499. COMMON slicer_common, dims, sl, z_last, zb_last, mode, fixed
  500. common colors, r_orig, g_orig, b_orig, r_curr, g_curr, b_curr
  501.  
  502. v = [0, .5, 1.]        ;Shading of the planes.
  503. if n_params() eq 0 then table = -1
  504. if table ge 0 then loadct, /SILENT, table
  505. SLICER_JOURNAL, "COLOR", [table, sl.stretch, 100. * sl.shading]
  506.  
  507. t = sl.stretch /100. * sl.nc3
  508. if t[1] eq t[0] then s = sl.nc3 else s = sl.nc3 / (t[1]-t[0])
  509. q = long(3*s*(findgen(sl.nc3) - t[0]))
  510.  
  511.  
  512. r_curr = bytarr(3*sl.nc3)
  513. g_curr = r_curr
  514. b_curr = r_curr
  515. s = 1.-sl.shading
  516. for i=0,2 do begin        ;3 faces
  517.     v0 = sl.shading * v[i] * 255
  518.     r_curr[i*sl.nc3] = s * r_orig[q] + v0
  519.     g_curr[i*sl.nc3] = s * g_orig[q] + v0
  520.     b_curr[i*sl.nc3] = s * b_orig[q] + v0
  521.     endfor
  522. tvlct, r_curr, g_curr, b_curr
  523.     ; load last 4 colors as red, green, blue, white
  524. tvlct, [255,0,0,255],[0,255,0,255],[0,0,255,255],3*sl.nc3
  525. end
  526.  
  527. PRO DO_ISOSURFACE        ;Draw the isosurface
  528. COMMON volume_data, a
  529. COMMON slicer_common, dims, sl, z_last, zb_last, mode, fixed
  530.  
  531.  
  532. WIDGET_CONTROL, sl.base, /HOURGLASS
  533. SLICER_JOURNAL, "ISO", [(sl.isop.value-sl.amin)/(sl.amax-sl.amin)*100, $
  534.         sl.isop.hi_lo]
  535. set_plot,'Z'
  536. widget_control, sl.pos_text, set_value='Computing Polygons'
  537. shade_volume, a, sl.isop.value, verts, polys, $
  538.     low = sl.isop.hi_lo
  539. if n_elements(verts) eq 0 then begin
  540.     widget_control, sl.pos_text, set_value = $
  541.     'No surface at this value'
  542.     set_plot,sl.gdev
  543. endif else begin
  544.   widget_control, sl.pos_text, set_value = $
  545.     strtrim((size(verts))[2],2)+' Vertices, ' + $
  546.     strtrim((size(polys))[1]/4,2) + ' Polygons.'
  547.   z_last = tvrd()            ;Save old display
  548.   zb_last = tvrd(CHANNEL=1, /WORDS)
  549.   SET_SHADING, Values=[0, sl.nc3-1]
  550.   b = polyshade(verts,polys,/T3D,top=sl.nc3-1)
  551.   verts = 0 & polys = 0        ;Free space
  552.   slicer_show
  553. endelse
  554. end
  555.  
  556.  
  557.  
  558. PRO draw_cube, c0, c1, faces, color
  559. ;    draw a cube whose opposite corners are [c0[0],c0(1),c0(2)],
  560. ;    and [c1[0], c1(1), p2(3)].
  561. ;    color = drawing color.
  562. COMMON volume_data, a
  563. COMMON slicer_common, dims, sl, z_last, zb_last, mode, fixed
  564. p0 = intarr(3,8)
  565. p1 = float(p0)
  566. cc = [[c0],[c1]]
  567. for i=0,7 do BEGIN
  568.     p0[0,i] = [ cc[0, i and 1], cc[1, (i/2 and 1)], cc[2, (i/4 and 1)]]
  569.     p1[0,i] = convert_coord(p0[*,i], /T3D,/TO_DEVICE,/DATA)
  570.     ENDFOR
  571.  
  572. if n_elements(color) le 0 THEN color = sl.nc1
  573. f = sl.facevs
  574. flags = bytarr(8,8)    ;line flags, dont draw same line twice
  575. for i=0,n_elements(faces)-1 do BEGIN
  576.     ff = [ f[*,faces[i]], f[0,faces[i]]]  ;Vertex indices
  577.     for j=0,3 do begin
  578.     k = ff[j] < ff[j+1] & l = ff[j] > ff[j+1]
  579.     if not flags[k,l] then plots, p1[*,[k,l]], color = color, /dev
  580.     flags[k,l] = 1
  581.     ENDFOR
  582.     ENDFOR
  583. end
  584.  
  585.  
  586.  
  587.  
  588.  
  589. PRO slicer_erase        ;draw the background
  590. ;    call with no params to erase all.
  591. COMMON volume_data, a
  592. COMMON slicer_common, dims, sl, z_last, zb_last, mode, fixed
  593.  
  594. SLICER_JOURNAL, "ERASE"
  595. set_plot,'Z'
  596. erase
  597. sl.p1 = convert_coord(sl.p0, /T3D, /TO_DEVICE, /DATA)  ;save dev coords
  598. s = strarr(8)
  599. for i=0,7 do BEGIN
  600.     s[i] = string(sl.p0[*,i],format ="(' (',i0,',',i0,',',i0,')')")
  601.     ENDFOR
  602. junk = max(sl.p1[2,*], j)
  603. sl.v_close = j            ;index of closest vertex
  604. p = where(sl.facevs eq sl.v_close)/4   ;indices of closest verts
  605. colors = [ sl.nc1, sl.nc3*3+1]  ;white, green
  606. for i=0,5 do BEGIN        ;draw faces
  607.     k= (where(p eq i))[0] lt 0     ;1 = not close, 0 = close
  608.     draw_cube, [0,0,0], dims-1, i, colors[k]
  609.     ENDFOR
  610. for i=0,7 do xyouts, sl.p1[0,i],sl.p1[1,i],/DEVICE,s[i], $
  611.     color=colors[i ne sl.v_close]
  612. z_last = tvrd()
  613. zb_last = tvrd(CHANNEL=1, /WORDS)
  614. slicer_show
  615. end
  616.  
  617.  
  618.  
  619. Function slicer_plane_int, dummy
  620. ; Return the intersections of the plane with the volume cube.
  621. ; V[3,12] = intersections of plane with the 12 edges.
  622. ; Flags[12] = 1 if there is an intersection at that edge.
  623. COMMON slicer_common, dims, sl, z_last, zb_last, mode, fixed
  624.  
  625. Jn = sl.orthop[0:2]            ;Plane eqn
  626. Jd = sl.orthop[3]
  627.  
  628. v = fltarr(3,12)
  629. k = 0
  630.  
  631. for i=0,11 do begin            ;Faces
  632.     p0 = sl.p0[*,sl.edges[0,i]]        ;Beginning of edge
  633.     p1 = sl.p0[*,sl.edges[1,i]]        ;End of edge
  634.     lv = p1-p0
  635.     t = total(lv * Jn)
  636.     if t ne 0 then begin
  637.     t = -(jd + total(p0 * Jn)) / t
  638.     p = p0 + t * lv            ;Point of intersection
  639.     d = min((p - p0) * (p1-p))
  640.     if d ge 0.0 then begin        ;Within edge?
  641.         v[0,k] = p            ;Yes, save intersection
  642.         k = k + 1
  643.         endif          
  644.     endif                ;T ne 0
  645.     endfor                    ;i
  646.  
  647. ; Sort into order:
  648. d = max(abs(Jn), m)            ;Largest plane coeff = what we ignore
  649. u = v[[m+1, m+2] mod 3, 0:k-1]        ;Get other 2 coords
  650. a = fltarr(k)                ;Angle measure
  651. d = min(u[1,*], dmin)            ;Get lowest point
  652. ;p0 = u[*,dmi])
  653. ;for i=0,k-1 do if i ne dmin then begin    ;Get angles
  654. ;    d = u[*,i] - p0            ;Dx,dy
  655. ;    d0 = total(abs(d))        ;abs(dx) + abs(dy)
  656. ;    if d0 ne 0. then begin
  657. ;        t = d(1) / d0        ;Proportional to angle w. horizontal
  658. ;        if d[0] lt 0. then t = 2. - t $
  659. ;        else if d(1) lt 0. then t = t + 4
  660. ;        endif else t = 0.
  661. ;    a[i] = t
  662. ;    endif
  663. u_dx = u[0,*]-u[0,dmin]
  664. u_dy = u[1,*]-u[1,dmin]
  665. zero_ind = Where((u_dx EQ 0.0) AND (u_dy EQ 0.0))
  666. if (zero_ind[0] GE 0L) THEN u_dx[zero_ind] = 1.0
  667. a=atan(u_dy, u_dx)
  668. zero_ind=0 & u_dx=0 & u_dy=0
  669. a[dmin] = -100.                ;Anchor = first
  670. n = sort(a)                ;Go around anchor point & back
  671. return, v[*, [n, n[0]]]
  672. end
  673.  
  674. PRO slicer_show, image
  675. ;move the Z buffer to the X display.  leave device set to X.
  676. ; if parameter is present, show it rather than reading the Z buffer
  677. COMMON volume_data, a
  678. COMMON slicer_common, dims, sl, z_last, zb_last, mode, fixed
  679.  
  680. if n_params() eq 0 then begin
  681.     set_plot,'Z'
  682.     image = tvrd()
  683.     endif
  684. set_plot,sl.gdev
  685. wset, sl.window
  686. tv, image
  687. sl.cube_on = 0
  688. end
  689.  
  690. PRO draw_orientation    ;draw the orientation cube in the small window
  691. ; Draw the outline of the 3 frontmost faces of the main cube.
  692. ; Draw the fixed axis plane in green.
  693. ; If the mode is cut or cube, draw the selected cube.  Draw the back faces
  694. ;    in blue, and label the selection points.
  695.  
  696. COMMON volume_data, a
  697. COMMON slicer_common, dims, sl, z_last, zb_last, mode, fixed
  698. COMMON slicer_common1, old_slice, d0, z0, az, el
  699.  
  700. i = sl.mode_bases[mode]
  701. widget_control, i, get_uvalue = draw        ;the widget id
  702. widget_control, draw[0], get_value=window    ;the window number
  703. wset, window
  704. device, set_graph = 3                ;Copy mode
  705. kc = 3 * sl.nc3 + 1                ;Drawing color
  706. erase
  707.  
  708. if mode le 0 then begin            ;Single slice?
  709.     if sl.ortho eq 0 then begin        ;Orthogonal?
  710.     mark_oblique, kc
  711.     goto, done
  712.     endif
  713.     z = [0,0,0]
  714.     d1 = dims-1
  715.   endif else begin            ;Block.
  716.     z = sl.p0cube[*,0] < sl.p0cube[*,1]
  717.     d1 = sl.p0cube[*,0] > sl.p0cube[*,1]
  718.   endelse
  719.                     ; draw fixed plane:
  720. nlines = 6
  721. p = z
  722. d = (d1-z) / float(nlines-1)
  723.  
  724. p[fixed] = (d1[fixed] + z[fixed])/2.
  725. d[fixed] = 0.0
  726.  
  727. for i=0,nlines-1 do BEGIN        ;draw fixed direction
  728.     xx = replicate(p[0],2)
  729.     yy = replicate(p[1],2)
  730.     zz = replicate(p[2],2)
  731.     if fixed ne 0 THEN plots, [z[0],d1[0]], yy,zz, /T3D, COLOR=kc, /DATA
  732.     if fixed ne 1 THEN plots, xx, [z[1],d1[1]],zz, /T3D, COLOR=kc, /DATA
  733.     if fixed ne 2 THEN plots, xx, yy, [z[2],d1[2]],/T3D, COLOR=kc, /DATA
  734.     p = p + d
  735.     ENDFOR
  736.  
  737. if mode ne 0 then begin        ;Do cube
  738.     draw_cube, sl.p0cube[*,0], sl.p0cube[*,1], indgen(6), kc+1  ;all faces
  739.         ;Close faces in white
  740.     draw_cube, sl.p0cube[*,0], sl.p0cube[*,1], $
  741.             where(sl.facevs eq sl.v_close)/4
  742.     for i=0,1 do begin        ;Label them
  743.         p = convert_coord(sl.p0cube[*,i], /T3D, /TO_DEV, /DATA)
  744.         xyouts, p[0], p[1], strtrim(i,2), /device
  745.         endfor
  746.     endif
  747.  
  748. done: 
  749. draw_cube, [0,0,0], dims-1, where(sl.facevs eq sl.v_close)/4  ;draw close faces
  750. wset, sl.window
  751. return
  752. end
  753.  
  754.  
  755. PRO mark_oblique, color            ;Draw an oblique slice
  756. COMMON slicer_common, dims, sl, z_last, zb_last, mode, fixed
  757. COMMON slicer_common1, old_slice, d0, z0, az, el
  758.  
  759. if n_elements(d0) lt 3 then return
  760.  
  761. plots, d0, /T3D, COLOR=color, /DATA
  762. z1 = [[z0], [z0]]
  763. for i=0,2 do begin
  764.     z2 = z1
  765.     z2[i,0] = 0. & z2[i,1] = dims[i]-1.
  766.     plots, z2, /T3D, COLOR = color, /DATA
  767.     endfor
  768. return
  769. end
  770.  
  771.  
  772.  
  773. PRO mark_slice, ev        ;mark a horizontal or vertical slice
  774.  
  775. COMMON volume_data, a
  776. COMMON slicer_common, dims, sl, z_last, zb_last, mode, fixed
  777. COMMON slicer_common1, old_slice, d0, z0, az, el
  778.  
  779. ;        loop until the mouse is released.
  780. oldbuttons = sl.lbuttons
  781. sl.lbuttons = oldbuttons and (not ev.release) or (ev.press)
  782. press = ev.press and 1            ;New left button press?
  783. p = float([ev.x, ev.y])            ;device coords of mouse
  784.  
  785. if (n_elements(old_slice) le 0) or (ev.press ne 0) then old_slice = -1
  786. kslice = -1                ;assume no face
  787. kc = sl.xcol                ;XOR drawing color
  788.  
  789. if sl.lbuttons and 1 THEN BEGIN        ;Marking a face?
  790.     f = where(sl.facevs eq sl.v_close)/4  ;3 faces to check that are front
  791.     d1 = dims-1
  792.     z1 = intarr(3)
  793.     d = ''
  794.     for i=0,2 do BEGIN            ;find the face
  795.     j = f[i]            ;face index
  796.     p1 = sl.p1[0:1, sl.facevs[*,j]]    ;vertices
  797.     if p_inside_poly(p1, p) THEN BEGIN
  798.         face = j
  799.         p = p / [ !d.x_size, !d.y_size]    ;Get data coords. normalized
  800.         face_dim = face mod 3    ;Fixed coord along face
  801.         if face le 2 THEN k = 0 ELSE k = dims[face_dim]-1
  802.         p = COORD2to3(p[0], p[1], face_dim, k, sl.pt_inverse)
  803.         ip = fix(p + 0.5)        ;round
  804.         if ip[fixed] ge dims[fixed] then goto, NO_BREAK    ;Outside
  805.         kslice = ip[fixed]        ;slice number
  806.         d1[fixed] = kslice
  807.         z1[fixed] = kslice
  808.         goto, NO_BREAK
  809.         ENDIF
  810.     ENDFOR
  811.   NO_BREAK:
  812. ENDIF                    ;Marking a face
  813.  
  814. device, SET_GRAPH=6             ;set XOR mode
  815. valid = kslice ge 0
  816.  
  817. if sl.ortho eq 0 then begin        ;Oblique???
  818.     if n_elements(az) eq 0 then begin    ;Initialize?
  819.     az = 0.  & el = 0. & z0 = dims / 2.
  820.     sl.orthop = [ 0., 0., 1., -total(dims)/2]
  821.     endif
  822.     el1 = el & az1 = az & z1 = z0    ;Old params
  823.     if (sl.lbuttons and 4) ne 0 then begin    ;New azimuth/elev?
  824.     if sl.oangle then $
  825.         el1 = fix((p[0]/!d.x_size * 198) - 99.) > (-90) < 90 $
  826.     else az1 = fix((p[0]/!d.x_size * 396) - 198.) > (-180) < 180
  827.     if (el1 ne el) or (az1 ne az) then begin
  828.         s = sin(el1 * !dtor)
  829.         sl.orthop[0] = sin(-az1 * !dtor) * s
  830.         sl.orthop[1] = cos(-az1 * !dtor) * s
  831.         sl.orthop[2] = cos(el1 * !dtor)
  832.         valid = 1
  833.         endif
  834.     endif else if valid then begin    ;New origin?
  835.     p[face_dim] = z0[face_dim]    ;New coords, 1 remains unchanged
  836.     z1 = p
  837.     valid = total(abs(z0-z1)) ne 0.    ;Change...
  838.     ENDIF
  839.  
  840.     if (valid) then begin        ;Draw new
  841.     sl.orthop[3] = -total(sl.orthop * z0)
  842.         IF old_slice gt 0 THEN mark_oblique, kc    ;Erase old
  843.     old_slice = 0
  844.     el = el1 & az = az1 & z0 = z1    ;New parameters
  845.     if valid and (sl.lbuttons ne 0) THEN BEGIN  ;Update obliq outline
  846.         WIDGET_CONTROL, sl.pos_text, set_value = $
  847.         STRING(z0, az, el, FORMAT="('(',3f5.1,') A=', i4, ' E=',i4)")
  848.         d0 = slicer_plane_int()        ;New intersections
  849.         mark_oblique, kc    ;Draw new
  850.         old_slice = 1        ;show its visible
  851.         ENDIF
  852.     ENDIF            ;Valid
  853.     if ev.release ne 0 then begin    ;Released button?
  854.     if old_slice then mark_oblique, kc
  855.     draw_orientation    ;Draw resulting plane
  856.     old_slice = 0
  857.     endif
  858. ENDIF ELSE BEGIN            ;Orthogonal.
  859.     IF (kslice ne old_slice) THEN BEGIN ;Movement?
  860.         if (press eq 0) and (old_slice ge 0)then $    ;Erase old?
  861.         draw_cube, z0, d0, fixed, kc
  862.     if valid then $
  863.           d = 'Position: ' + string(ip, format="('(',i4,',',i4,',',i4,')')") $
  864.     else d = ''
  865.     WIDGET_CONTROL, sl.pos_text, set_value=d
  866.     if valid and sl.lbuttons THEN BEGIN
  867.         draw_cube, z1, d1, fixed, kc
  868.         z0 = z1
  869.         d0 = d1
  870.         ENDIF
  871.     IF (ev.release eq 1) and (old_slice ge 0) THEN BEGIN
  872.         device, SET_GRAPH=3
  873.         slicer_draw, fixed, old_slice    ;Mark the slice
  874.         ENDIF            ;Release
  875.     old_slice = kslice        ;Save current position
  876.     ENDIF                ;Movement
  877. ENDELSE
  878.  
  879. device, SET_GRAPH=3    ;normal mode
  880. end
  881.  
  882.  
  883. PRO do_cube                ;Draw a cube or cut
  884. COMMON volume_data, a
  885. COMMON slicer_common, dims, sl, z_last, zb_last, mode, fixed
  886.  
  887. WIDGET_CONTROL, sl.base, /HOURGLASS
  888. SET_PLOT, 'Z'
  889. z =  (z_last = tvrd())            ;Save previous image & current cont
  890. zb = (zb_last = tvrd(CHANNEL=1, /WORDS))
  891.  
  892.  
  893. SLICER_JOURNAL, "TRANS", [sl.trans, sl.threshold * 100. / sl.nc3]
  894. SLICER_JOURNAL, "CUBE", [ mode, sl.cut_ovr, sl.interp, reform(sl.p0cube, 6) ]
  895.  
  896. d0 = sl.p0cube[*,0] < sl.p0cube[*,1]        ;Lower corner
  897. d1 =  (sl.p0cube[*,0] > sl.p0cube[*,1]) -d0
  898. coords = fltarr(3,8)
  899. for i=0,7 do coords[0,i] = $        ;Verts of our cube
  900.    [ (i and 1) * d1[0], (i and 2)/2 *d1[1], (i and 4)/4 * d1[2]] + d0
  901. faces = where(sl.facevs eq sl.v_close)/4   ;close faces
  902. relation = mode eq 1
  903.  
  904. FOR face = 0, 5 do $            ;Draw the faces of the cube or cut
  905.   IF ((where(face eq faces))[0] ge 0) eq relation then begin  ;Do this face?
  906.     v = 0 & ones = 0 & z0 = 0 & q = 0    ;Clear things out
  907.     erase                    ;Reset Z buffer
  908.     verts = sl.facevs[*,face]        ;Vertices
  909.     polyfill, coords[*, verts], /T3D    ;Draw polygon for face
  910.     z0 = tvrd(CHANNEL=1, /WORDS)        ;Now read the Z buffer
  911.     if mode eq 1 then $            ;Cube? or Cut?
  912.         points = where(z0 gt zb) $    ;New points for cube
  913.     else if sl.cut_ovr then points = where(z0 ne z0[0,0]) $ ;Cut mode?
  914.     else points = where((z0 ne z0[0,0] and (zb gt z0)))  ;Over mode
  915.  
  916.     widget_control, sl.pos_text, set_value = $
  917.         'Creating face ' + strtrim(face,2)
  918.     if points[0] ne -1 THEN    BEGIN        ;Anything to do?
  919. ;        Get volume coords of plane:
  920.       v = p_inverse(points mod !d.x_size, points / !d.x_size, z0[points])
  921. ;        Either interpolate or pick nearest neighbor
  922.       widget_control, sl.pos_text, set_value = $
  923.         (['Sampling','Interpolating'])[sl.interp] + $
  924.         ' face ' + strtrim(face,2) + ',  ' + $
  925.         strtrim(n_elements(v)/3,2) + ' Pixels'
  926.  
  927.       if sl.interp THEN v = interpolate(a, v[*,0], v[*,1], v[*,2]) $
  928.       else begin
  929.         v = round(v)
  930.         v = a[long(temporary(v)) # [1, dims[0], dims[0] * dims[1]]]
  931.         endelse
  932.                     ;Update our points
  933.       if sl.trans THEN BEGIN    ;Transparency?
  934.         good = where(v ge sl.threshold, count)
  935.         if count le 0 then goto, skipit
  936.         v = v[good]
  937.         points = points[good]
  938.         endif
  939.       offset = byte((face mod 3) * sl.nc3)   ;Offset
  940.       q = bytscl(v, max=sl.amax, min=sl.amin, top = sl.nc3-1) ;face data
  941.                    ;Get subscripts in data cube
  942.       if offset ne 0 then q = q + offset
  943.       z[points] = q            ;Store the new face
  944.       zb[points] = z0[points]    ;in both buffers
  945.     skipit:
  946.     ENDIF                ;Anything to do
  947.   ENDIF                    ;Each face
  948. tv, z                    ;Now show it
  949. tv, zb, /WORDS, CHANNEL=1        ;and update depth buffer
  950. v = 0 & ones = 0 & z0 = 0 & q = 0    ;Clear things out
  951. z = 0 & zb = 0
  952. widget_control, sl.pos_text, set_value = 'Done.'
  953. slicer_show
  954. end
  955.  
  956.  
  957.  
  958.  
  959. PRO mark_cube1, p0, ip    ;Draw the outline of the cube in the main drawable
  960. ; p0 = cube coordinates (3,2).
  961. ; ip = index of corner that is marked (0 or 1).
  962. COMMON volume_data, a
  963. COMMON slicer_common, dims, sl, z_last, zb_last, mode, fixed
  964.  
  965. draw_cube, p0[*,0],p0[*,1], indgen(6), sl.xcol   ;Basic cube
  966. p1 = [[p0[*,ip]], [p0[*,ip]]]
  967. p = sl.p0[*,sl.v_close]
  968. for i=0,2 do begin        ;Lines to faces
  969.     p1[i,0] = p[i]
  970.     plots, p1, color=128, /T3D
  971.     p1[i,0] = p1[i,1]
  972.     endfor
  973. end
  974.  
  975.  
  976.  
  977. PRO mark_cube, ev            ;Mark a cube in the main window
  978. ;  Use the XOR graphics mode to avoid killing the display
  979. COMMON volume_data, a
  980. COMMON slicer_common, dims, sl, z_last, zb_last, mode, fixed
  981.  
  982. if n_params() eq 0 then    begin        ;Erase old cube?
  983.     device, SET_GRAPHICS = 6    ;Set XOR mode
  984.     if sl.cube_on then mark_cube1, sl.p0cube, sl.cube_ip
  985.     sl.cube_on = 0
  986.     device, SET_GRAPHICS=3
  987.     return
  988.     ENDIF
  989.  
  990. oldbuttons = sl.lbuttons
  991. sl.lbuttons = oldbuttons and (not ev.release) or (ev.press)
  992. press = ev.press and 1            ;New left button press?
  993.  
  994. if sl.lbuttons eq 0 then begin        ;Released all buttons?
  995.     if oldbuttons ne 0 then draw_orientation  ;Update viewbox
  996.     return
  997.     ENDIF
  998.  
  999. x = ev.x / float(!d.x_size)        ;Normalized coords
  1000. y = ev.y / float(!d.y_size)
  1001. d1 = dims -1
  1002.  
  1003. p0cube = sl.p0cube        ;Save old coords
  1004. cube_ip = sl.cube_ip
  1005.  
  1006. sl.cube_ip = sl.lbuttons eq 2        ;Corner index
  1007. q = sl.p0cube[fixed, sl.cube_ip]    ;Fixed axis/point
  1008. p = fix(COORD2TO3(x, y, fixed, q, pti)+0.5) ;3D coords
  1009. sl.p0cube[*,sl.cube_ip] = p < d1 > 0    ;New corner value
  1010. sl.p0cube[fixed, sl.cube_ip] = q
  1011. if (total(abs(sl.p0cube - p0cube)) eq 0.0) and $ ;No change?
  1012.    cube_ip eq sl.cube_ip then return
  1013.  
  1014. device, SET_GRAPHICS = 6    ;Set XOR mode
  1015. if sl.cube_on then mark_cube1, p0cube, cube_ip  ;Erase prev
  1016. sl.cube_on = 1
  1017. mark_cube1, sl.p0cube, sl.cube_ip
  1018. d = string(sl.p0cube, format="('(', 3i4, ') (', 3i4, ')')")
  1019. widget_control, sl.pos_text, set_value = d  ;label it
  1020. DEVICE, SET_GRAPHICS = 3        ;Restore
  1021. end
  1022.  
  1023.  
  1024.  
  1025.  
  1026.  
  1027. PRO slicer_event, ev
  1028. COMMON volume_data, a
  1029. COMMON slicer_common, dims, sl, z_last, zb_last, mode, fixed
  1030.  
  1031.  
  1032. swin = !d.window
  1033. wset, sl.window        ;Our window
  1034.  
  1035. if ev.id eq sl.draw THEN BEGIN        ;mouse press?
  1036.   IF mode le 2 THEN BEGIN        ;Slice or cube mode?
  1037.     IF  ((ev.press and 4) ne 0) and sl.ortho THEN BEGIN  ;Right but= chg plane?
  1038.     fixed = (fixed + 1) mod 3    ;bump plane
  1039.     draw_orientation
  1040.     goto, clean_exit
  1041.     ENDIF    
  1042.     if mode eq 0 then BEGIN        ;Slice mode?
  1043.     if (ev.press and 2) ne 0 then goto, probe_it  ;Middle = probe
  1044.     i = sl.lbuttons or ev.press    ;New state
  1045.     if ((sl.ortho eq 0) and (i ne 0)) or (sl.ortho and i) THEN BEGIN
  1046.         mark_slice, ev        ;mark the slice
  1047.         goto, clean_exit
  1048.         endif
  1049.     ENDIF ELSE if mode le 2 THEN BEGIN
  1050.     mark_cube, ev             ;Move the cube
  1051.     ENDIF
  1052.     goto, clean_exit
  1053.   ENDIF    ELSE BEGIN            ;Other modes
  1054.     if ev.press eq 0 then goto, clean_exit
  1055.   probe_it: if (n_elements(zb_last) le 1) THEN goto, clean_exit
  1056.     set_plot,'Z'
  1057.     z = tvrd(ev.x, ev.y, /WORD, /CHANNEL)  ;Z-buffer value at x,y
  1058.     set_plot,sl.gdev
  1059.     d = 'No Data Value'
  1060.     if z[0] gt -32760 THEN BEGIN    ;anything there?
  1061.       p = p_inverse(ev.x, ev.y, z[0])  ;To object coords
  1062.       p = round(p)            ;round
  1063.       p = p > 0 < (dims-1)        ;to range
  1064.       x = a[p[0], p[1], p[2]] + 0
  1065.       y = fix(100.*(x - sl.amin)/(sl.amax - sl.amin))  ;To %
  1066.       d = 'Position: '+string(p,format="('(',i0,',',i0,',',i0,')')") + $
  1067.         ', Data= ' + strtrim(x,2) + ' (' + strtrim(y,2) + '%)'
  1068.     ENDIF            ;Something there
  1069.     widget_control, sl.pos_text, set_value = d
  1070.   ENDELSE
  1071.   goto, clean_exit
  1072. ENDIF            ;Drawable window
  1073.  
  1074. if ev.id eq sl.isop.drawable then begin        ;Isosurface threshold
  1075.     if ev.press eq 0 then goto, clean_exit
  1076.     x = (ev.x - sl.isop.xs[0]) / sl.isop.xs[1]
  1077.     x = x > sl.amin < sl.amax
  1078.     WIDGET_CONTROL, sl.isop.slider, $
  1079.        SET_VALUE = 100.*(x - sl.amin) / (sl.amax-sl.amin)
  1080.     sl.isop.value = x
  1081.     goto, clean_exit
  1082.     ENDIF
  1083. if ev.id eq sl.file_text[0] then $
  1084.     goto, clean_exit             ;Ignore return in file name widget
  1085. if ev.id eq sl.rslide[2] then BEGIN
  1086.     slicer_orientation
  1087.     goto, clean_exit
  1088.     ENDIF
  1089. ;        here, it must be a button or a slider:
  1090. widget_control, ev.id, get_uvalue = eventval
  1091. case eventval of
  1092. "CANCUBE" : mark_cube        ;Undraw outline
  1093. "COLORS" : slicer_colors, (where(sl.color_button eq ev.id))[0]
  1094. "CUTINTO": sl.cut_ovr = 0
  1095. "CUTOVER": sl.cut_ovr = 1
  1096. "ERASE"  : slicer_erase
  1097. "EXIT"   : BEGIN
  1098.     widget_control, ev.top, /DESTROY
  1099.     if sl.rbase ne 0 then WIDGET_CONTROL, sl.rbase, /DESTROY
  1100.     z_last = 0
  1101.     zb_last = 0
  1102.     goto, close_journal
  1103.     ENDCASE
  1104. "EXPOSE0": sl.expose = 0
  1105. "EXPOSE1": sl.expose = 1
  1106. "GOCUBE" : do_cube
  1107. "HELP" : BEGIN
  1108.     xdisplayfile, filepath("slicer.txt", subdir=['help', 'widget']), $
  1109.         title = "Slicer help", $
  1110.         group = ev.top, $
  1111.         width = 72, height = 24
  1112.     goto, clean_exit
  1113.     ENDCASE
  1114.  
  1115. "INTERP0": BEGIN
  1116.     sl.interp = 0
  1117.     goto, set_interp
  1118.     ENDCASE
  1119. "INTERP1": BEGIN
  1120.     sl.interp = 1
  1121.   set_interp:  i = WIDGET_INFO(ev.id, /parent)
  1122.     WIDGET_CONTROL, i, GET_UVALUE = i    ;Buttons
  1123.     WIDGET_CONTROL, i[1-sl.interp], /SENS
  1124.     WIDGET_CONTROL, i[sl.interp], SENS=0
  1125.     ENDCASE
  1126.  
  1127. "ORTHO0":  BEGIN            ;On oblique
  1128.     sl.ortho = 0
  1129.     WIDGET_CONTROL, sl.obuttons, MAP=1
  1130.     draw_orientation
  1131.     ENDCASE
  1132. "ORTHO1":  BEGIN
  1133.     sl.ortho = 1
  1134.     WIDGET_CONTROL, sl.obuttons, MAP=0
  1135.     draw_orientation
  1136.     ENDCASE
  1137. "AZIM" : sl.oangle = 0
  1138. "ELEV" : sl.oangle = 1
  1139. "GOOBL" :  BEGIN            ;Do an oblique slice
  1140.     WIDGET_CONTROL, ev.top, /HOURGLASS
  1141.     slicer_oblique
  1142.     end
  1143.  
  1144.  
  1145. "ORIENTATION": SLICER_ORIENTATION, (where(sl.ori_butt eq ev.id))[0]
  1146. "PLAYBACK" : BEGIN
  1147.     WIDGET_CONTROL, sl.file_text[0], GET_VALUE=name
  1148.     name = strtrim(name[0],2)
  1149.     SLICER_PLAYBACK, FILE = name
  1150.     ENDCASE
  1151. "RECORD" : BEGIN
  1152. start_journal: if sl.journal ne 0 then free_lun, sl.journal  ;Close old
  1153.     sl.journal = 0
  1154.     WIDGET_CONTROL, sl.file_text[0], GET_VALUE=name
  1155.     name = strtrim(name[0])
  1156.     openw, i, name, ERROR=j, /GET_LUN
  1157.     if j ne 0 then begin        ;OK?
  1158.         widget_control, sl.file_text[1], set_value = !ERR_STRING
  1159.         goto, clean_exit
  1160.         ENDIF
  1161.     widget_control, sl.file_text[1], set_value = 'Journal Active'
  1162.     sl.journal = i
  1163.     ENDCASE
  1164. "RECORDOFF" : BEGIN
  1165.     widget_control, sl.file_text[1], set_value = 'Journal Closed'
  1166. close_journal: if sl.journal ne 0 then free_lun, sl.journal  ;Close old
  1167.     sl.journal = 0
  1168.     ENDCASE
  1169. "THRESHOLD" : BEGIN
  1170.     sl.threshold = sl.nc3 * ev.value / 100.
  1171.     sl.trans = (ev.value ge 1) and (ev.value le 99)  ;On if reasonable
  1172.     ENDCASE
  1173. "HIGH": sl.isop.hi_lo = 0
  1174. "LOW" : sl.isop.hi_lo = 1
  1175. "ISOSLIDE" : sl.isop.value = (ev.value / 100.)*(sl.amax-sl.amin) + sl.amin
  1176. "GO":   do_isosurface
  1177. "SHADING": BEGIN
  1178.     sl.shading = ev.value /100.
  1179.     slicer_colors
  1180.     ENDCASE
  1181. "STMAX": BEGIN
  1182.     sl.stretch[1] = ev.value
  1183.     slicer_colors
  1184.     ENDCASE
  1185. "STMIN": BEGIN
  1186.     sl.stretch[0] = ev.value
  1187.     slicer_colors
  1188.     ENDCASE
  1189. "UNDO" : slicer_undo
  1190. "XROTATION": BEGIN
  1191.     sl.rotation[0] = ev.value
  1192.     slicer_orientation
  1193.     ENDCASE
  1194. "ZROTATION": BEGIN
  1195.     sl.rotation[1] = ev.value
  1196.     slicer_orientation
  1197.     ENDCASE
  1198.  
  1199. ELSE :   BEGIN            ;mode button?
  1200.     k = where(eventval eq sl.mode_names, count)  ;Match with mode name?
  1201.     if count eq 1 THEN BEGIN        ;switch mode
  1202.         if sl.cube_on then mark_cube    ;Remove the cube if vis
  1203.         fixed = 0            ;Reset fixed direction
  1204.         if sl.mode_bases[mode] ne 0 THEN $  ;Remove panel if mapped
  1205.             WIDGET_CONTROL, sl.mode_bases[mode], MAP=0
  1206.         mode = k[0]            ;New mode
  1207.         if sl.mode_bases[mode] ne 0 THEN $  ;Map new base
  1208.             WIDGET_CONTROL, sl.mode_bases[mode], MAP=1
  1209.         if mode le 2 THEN BEGIN        ;Slice or cube?
  1210.             draw_orientation
  1211.             ENDIF
  1212.         if mode eq 3 THEN BEGIN        ;Draw histogram
  1213.             WSET, sl.isop.window
  1214.             type = size(a)
  1215.             int = type[type[0] + 1] le 3  ;True if int type
  1216.             j = (sl.amax -sl.amin)/100. ;bin size
  1217.             if int then j = j > 1
  1218.             h = histogram(a, max=sl.amax, min = sl.amin, bin=j)
  1219.             if int THEN j = fix(j + .99)
  1220.             k = sort(h)
  1221.             n = n_elements(h)
  1222.             x = findgen(n) * j + sl.amin < sl.amax
  1223.             xsave = !x.s & ysave = !y.s
  1224.             PLOT,x,h, xst = 9, yst=8, ymargin=[2,0], $
  1225.                 yrange= [0,h[k[n-8]]], yticks=1, chars=.75, $
  1226.                 xticks=4
  1227.             sl.isop.xs = !x.s * !d.x_size
  1228.             WSET, sl.window
  1229.             !x.s = xsave & !y.s = ysave
  1230.             ENDIF            ;Isosurface
  1231.         widget_control, sl.obuttons, $    ;Oblique controls
  1232.             MAP = (mode eq 0) and (sl.ortho eq 0)
  1233.         goto, clean_exit
  1234.     ENDIF
  1235.     print,'Unknown event: ', eventval
  1236.     help, /STRUCT, ev
  1237.     ENDCASE
  1238. ENDCASE
  1239.  
  1240. clean_exit:
  1241.   wset, swin
  1242. end
  1243.  
  1244. PRO slicer, GROUP = group, RANGE = range, COMMANDS = commands, $
  1245.     CMD_FILE = cmd_file, RESOLUTION = resolution, DETACHED = detached, $
  1246.         MODAL = modal
  1247. ;+
  1248. ; NAME:
  1249. ;    SLICER
  1250. ;
  1251. ; PURPOSE:
  1252. ;    Widget based application to show 3D volume slices and isosurfaces.
  1253. ;
  1254. ; CATEGORY:
  1255. ;    Volume display / rendering.
  1256. ;
  1257. ; CALLING SEQUENCE:
  1258. ;    COMMON VOLUME_DATA, A
  1259. ;    A = your_volume_data
  1260. ;    SLICER
  1261. ;
  1262. ; INPUTS:
  1263. ;    Variable A in VOLUME_DATA common contains volume data.  See EXAMPLE
  1264. ;    section below.
  1265. ;
  1266. ; KEYWORD PARAMETERS:
  1267. ;     COMMANDS:    An optional string array of commands to execute
  1268. ;        before entering the interactive mode.  Commands are
  1269. ;        in the form of a keyword optionally followed one or more 
  1270. ;        numeric, blank-separated parameters.  For example:
  1271. ;            "COMMAND P1 P2 P3 ... Pn"
  1272. ;        Keywords and parameters are:
  1273. ;        UNDO:    Undo previous operation.
  1274. ;        ORI X_Axis Y_Axis Z_axis X_Rev Y_Rev Z_Rev X_Rot Z_Rot Asp
  1275. ;            This command sets the orientation for the SLICER 
  1276. ;            display.  X_Axis, Y_Axis, and Z_Axis should be 0 for 
  1277. ;            data x, 1 for data y, and 2 for data z.  
  1278. ;            X_Rev, Y_Rev, and Z_Rev should be 0 for normal, 1 for 
  1279. ;            reversed.  Asp is the Z axis aspect ratio w/ respect 
  1280. ;            to X, Y.  X_Rot and Z_Rot are the rotations of the 
  1281. ;            X and Z axes in degrees (30 is the default).
  1282. ;            For example, to interchange the X and Z axes and
  1283. ;            reverse the Y use the string:
  1284. ;                ORI 2 1 0 0 1 0 30 30
  1285. ;        TRANS On_Off Threshold:  Use this command to turn transparency 
  1286. ;            on or off and set the transparency threshold value.
  1287. ;            1 means on, 0 means off.  Threshold is expressed in 
  1288. ;            percent of data range (0 = min data value, 100 = max 
  1289. ;            data value).
  1290. ;        SLICE Axis Value Interp 0:  Draw an orthogonal slice along
  1291. ;            the given axis (0=x, 1=y, 2=z) at Value.  Set Interp
  1292. ;            equal to 1 for interpolation, 0 for nearest neighbor.
  1293. ;            Expose = 1 to remove, 0 for normal slice.
  1294. ;        SLICE Azimuth, Elev, Interp, Expose, 1, x0, y0, z0:  Draw
  1295. ;            an oblique slice.  The oblique plane crosses the
  1296. ;            XY plane at angle Azimuth, with an elevation of Elev.
  1297. ;            It passes thru the point (x0, y0, z0).
  1298. ;        COLOR Table_Index Low High Shading:  Set the color tables.
  1299. ;            Table_Index is the pre-defined color table number (see
  1300. ;            LOADCT), or -1 to retain the present table.  Low, High
  1301. ;            and Shading are expressed in percent.
  1302. ;        ISO Threshold Hi_Lo:  Draw an iso-surface.  Threshold is the 
  1303. ;            isosurface threshold value.  Hi_Lo should be set to 1
  1304. ;            to view the low side, 0 for the high side.
  1305. ;        ERASE:    Erase the display.
  1306. ;        CUBE Mode Cut_Ovr Interp X0 Y0 Z0 X1 Y1 Z1:  Draw cube 
  1307. ;            (mode = 1) or cut-out (mode = 0).
  1308. ;            Cut_Ovr should be set to  1 for cut-over, 0 for 
  1309. ;            cut-thru.  Interp should be 1 for interpolation, 0 
  1310. ;            for nearest neighbor.  (X0,Y0,Z0) is the lower corner 
  1311. ;            of the cube.  (X1,Y1,Z1) is the upper corner. 
  1312. ;            (X0 < X1, etc.)
  1313. ;        WAIT Secs:  Wait the designated time (in seconds).
  1314. ;
  1315. ;     CMD_FILE:    A string that contains the name of a file containing SLICER
  1316. ;        commands to execute as described above.
  1317. ;
  1318. ;    DETACHED: if set, put the drawable in a separate window. (Good
  1319. ;        for large windows.)
  1320. ;    GROUP:    The base ID of the widget that calls SLICER.  When this 
  1321. ;        keyword is specified, the death of the caller results in the
  1322. ;        death of the SLICER.
  1323. ;
  1324. ;    RANGE:    A two-element array containing minimum and maximum data
  1325. ;        values of interest.  If this keyword is omitted, the data is 
  1326. ;        scanned for the minimum and maximum.
  1327. ;       MODAL:  If set, then the slicer runs in modal mode.
  1328. ;
  1329. ;    RESOLUTION: a two element vector giving the width and height of
  1330. ;        the drawing window.  Default = 55% by 44% of screen width.
  1331. ; OUTPUTS:
  1332. ;    No explicit outputs.
  1333. ;
  1334. ; COMMON BLOCKS:
  1335. ;    COMMON VOLUME_DATA, A   ;Used to pass in the volume data.
  1336. ;    COMMON SLICER_COMMON   ;Used internally.
  1337. ;    COMMON SLICER_COMMON1  ;Used internally.
  1338. ;
  1339. ; SIDE EFFECTS:
  1340. ;    On exit, the Z-buffer contains the most recent image generated by
  1341. ;    SLICER.  The image may be redisplayed on a different device by 
  1342. ;    reading the Z-buffer contents, plus the current color table.
  1343. ;    Widgets are created on the X window display.
  1344. ;
  1345. ; RESTRICTIONS:
  1346. ;    Widgets are required.
  1347. ;    The volume data must fit in memory.
  1348. ;
  1349. ; PROCEDURE:
  1350. ;    The slicer program has the following modes:
  1351. ;    Slices:         Displays orthogonal slices thru the data volume.
  1352. ;    Block:          Displaces the surfaces of a selected block inside
  1353. ;                    the volume. 
  1354. ;    Cutout:         Cuts blocks from previously drawn objects.
  1355. ;    Isosurface:     Draws an isosurface contour.
  1356. ;    Probe:          Displays the position and value of objects
  1357. ;                    using the mouse.
  1358. ;    Colors:         Manipulates the color tables and contrast.
  1359. ;    Rotations:      Sets the orientation of the display.
  1360. ;
  1361. ; EXAMPLE:
  1362. ;    Data is transferred to the SLICER via the VOLUME_DATA common block
  1363. ;    instead of as an argument.  This technique is used because volume
  1364. ;    datasets can be very large and hence, the duplication that occurs when
  1365. ;    passing values as arguments is a waste of memory.  Suppose that you 
  1366. ;    want to read some data from the file "head.dat" into IDL for use
  1367. ;    in the SLICER.  Before you read the data, establish the VOLUME_DATA
  1368. ;    common block with the command:
  1369. ;
  1370. ;        COMMON VOLUME_DATA, VOL
  1371. ;
  1372. ;    The VOLUME_DATA common block has just one variable in it.  The variable
  1373. ;    can have any name.  Here, we're using the name "VOL".  Now read the
  1374. ;    data from the file into VOL.  For example:
  1375. ;
  1376. ;        OPENR, 1, "head.dat"
  1377. ;        VOL = FLTARR(20, 30, 42)
  1378. ;        READU, 1, VOL
  1379. ;        CLOSE, 1
  1380. ;
  1381. ;    Now you can run the SLICER widget application by entering:
  1382. ;
  1383. ;        SLICER
  1384. ;
  1385. ;    The data stored in VOL is the data being worked on by the SLICER.
  1386. ;
  1387. ;    To obtain the image in the slicer window after slicer is finished:
  1388. ;    (Use the image with the current color tables).
  1389. ;
  1390. ;    SET_PLOT, 'Z'   ;Use the Z buffer graphics device
  1391. ;    a = TVRD()    ;Read the image
  1392. ;
  1393. ; MODIFICATION HISTORY:
  1394. ;    DMS - RSI, Oct, 1991.
  1395. ;    DMS - RSI, Mar, 1992.  Added Journaling and expose mode.
  1396. ;                Fixed bug with 24 bit color.
  1397. ;    DMS - RSI, Jan, 1993.  Added oblique slices.
  1398. ;    bmh - 10/14/93 - The following minor bug fixes.
  1399. ;                  When no elements are found during an iso-surface display,
  1400. ;                  an error message was displayed to an invalid device name.
  1401. ;                  When no oblique slices are selected, the slicer_oblique
  1402. ;                  should return.
  1403. ;       DJC - RSI, Jun, 1994.  Fixed oblique slice initialization and
  1404. ;                              atan(0,0) problem (on HP).
  1405. ;       DJC - RSI, Feb, 1995.  Added modal keyword.
  1406. ;       DJC - RSI, Feb, 1995.  Changed "poly" variable to "polyv" to
  1407. ;                              avoid clash with math "poly" function.
  1408. ;       DJC - RSI, Mar, 1995.  Fixed shading values for iso-surface.
  1409. ;-
  1410.  
  1411.  
  1412.  
  1413. COMMON volume_data, a
  1414. COMMON slicer_common, dims, sl, z_last, zb_last, mode, fixed
  1415. COMMON slicer_common1, old_slice, d0, z0, az, el
  1416.  
  1417.  
  1418.  
  1419. swin = !d.window
  1420. mode = 0
  1421. fixed = 0
  1422. sl_width = 240        ;Slider width
  1423.  
  1424. mode_names = [ 'Slices', 'Block', 'Cutout', 'Isosurface', 'Probe', 'Colors', $
  1425.     'Rotations', 'Journal' ]
  1426. nmodes = n_elements(mode_names)        ;# of modes
  1427.  
  1428. isop = { ISOP, hi_lo : 1, value: 0.0, window : 0, drawable : 0L, slider : 0L, $
  1429.         xs : fltarr(2) }
  1430.  
  1431. ;    Main data structure
  1432. sl = {  SLICER, base : 0L, $        ;Main base
  1433.     draw:0L, $            ;Big drawable
  1434.     window:0, $            ;Big drawable window index
  1435.     trans:0, $            ;Transparency flag
  1436.     threshold_slider: 0L, $        ;Threshold slider 
  1437.     threshold:0b, $            ;Transp threshold in pixel values
  1438.     mode_names : mode_names, $    ;Names of modes
  1439.     interp: 1, $            ;Interpolation flag
  1440.     ortho : 1, $            ;TRUE for orthogonal slices
  1441.     orthop : fltarr(4), $        ;Plane eqn for ortho slices
  1442.     mode_bases : lonarr(nmodes), $    ;Mode panel bases
  1443.     nc3: 0, $            ;# of colors per partition (3 of them)
  1444.     nc1: 0, $            ;# of colors we use
  1445.     amax : 0.0, $            ;Data max, min
  1446.     amin : 0.0, $
  1447.     xcol : 0, $            ;XOR Drawing color
  1448.     color_button:lonarr(24), $    ;Color  table buttons (up to 24)
  1449.     axex: intarr(3), $        ;TRUE to reverse axis
  1450.     axrev: intarr(3), $        ;Axis permutations
  1451.     ori_butt: lonarr(7), $        ;Orientation buttons
  1452.     draw_butt: lonarr(4), $        ;Slice draw/expose buttons
  1453.     pos_text : 0L, $        ;Label widget at bottom
  1454.     rotation: [ 30., 30.], $    ;Current rotations
  1455.     v_close: 0, $            ;Index of closest vertex
  1456.     p0 : fltarr(3,8), $        ;Data coords of cube corners
  1457.     p1 : fltarr(3,8), $        ;Device coords of cube corners
  1458.     pt_inverse : fltarr(4,4), $    ;Inverse of !P.T
  1459.     vfaces : intarr(3,8), $        ;Face index vs vertex index
  1460.     facevs : intarr(4,6), $        ;Vertex index vs faces
  1461.     edges : intarr(2,12), $        ;Vertices vs edge index
  1462.     isop: isop, $            ;Isosurface parameters
  1463.     p0cube : intarr(3,2), $        ;Corner coords of cube selection
  1464.     cut_ovr : 0, $            ;Cut mode
  1465.     cube_on : 0, $            ;If cube is on
  1466.     cube_ip : 0, $            ;Corner of cube
  1467.     shading : 0.20, $        ;Amount of differential shading
  1468.     file_text : LONARR(2), $    ;File name text widgets
  1469.     cslide : LONARR(3), $        ;Color sliders
  1470.     rslide : LONARR(3), $        ;Rotation sliders, aspect text
  1471.     journal : 0, $            ;Journal file
  1472.     stretch : [0,100], $        ;Stretch params
  1473.     lbuttons : 0, $            ;Last button state
  1474.     expose : 0, $            ;Sice mode (0=slice, 1=expose)
  1475.     gdev : !D.NAME, $        ;Graphics device
  1476.     obuttons : 0L, $        ;Oblique buttons
  1477.     oangle : 1, $            ;active angle for oblique
  1478.     rbase: 0L }            ;Drawable base
  1479.  
  1480. ;  Faces vs vertex index
  1481. sl.vfaces = [[0,1,2],[1,2,3],[0,2,4],[2,3,4],[0,1,5], [1,3,5], [0,4,5], $
  1482.         [3,4,5]]
  1483. ;  Vertex indices vs faces  (clockwise order).
  1484. sl.facevs = [ [0,2,6,4], [0,4,5,1], [2,0,1,3], [1,5,7,3], [3,7,6,2], $
  1485.         [6,7,5,4]]
  1486. ;
  1487. ; vertex numbers vs Edge index (12 edges)
  1488. sl.edges = [[0,1],[1,3],[2,3],[0,2], [0,4], [1,5],[2,6],[3,7], $
  1489.       [4,5],[5,7],[6,7],[4,6]]
  1490.  
  1491. if XRegistered("slicer") THEN RETURN
  1492. if n_elements(resolution) lt 2 then begin
  1493.     device, get_screen = resolution
  1494.     resolution[0] = 5 * resolution[0] / 9
  1495.     resolution[1] = 4 * resolution[0] / 5
  1496.     endif
  1497.  
  1498. set_plot,'Z'
  1499. device, /z_buffering, set_resolution = resolution
  1500. set_plot,sl.gdev
  1501.  
  1502. z_last = 0
  1503. zb_last = 0
  1504.  
  1505. s = size(a)
  1506. if s[0] ne 3 THEN $
  1507.     MESSAGE,'Slicer: volume_data common block does not contain 3D data'
  1508. dims = s[1:3]
  1509. d1 = dims-1
  1510.  
  1511. sl.p0cube = [[dims/4], [3 * dims/4]]
  1512. for i=0,7 do sl.p0[*,i] = $        ;Data coords of corners
  1513.     [ (i and 1) * d1[0], (i and 2)/2 * d1[1], (i and 4)/4 * d1[2]]
  1514.  
  1515. sl.orthop = [ 0., 0., 1., -dims[2]/2.]    ;Initial orthogonal plane
  1516.  
  1517. if n_elements(range) ge 2 THEN BEGIN    ;Range specified?
  1518.     sl.amax = range[1]
  1519.     sl.amin = range[0]
  1520. ENDIF ELSE BEGIN
  1521.     sl.amax = max(a, min = q)
  1522.     sl.amin = q
  1523. ENDELSE
  1524.  
  1525. old_slice = 0
  1526. az = 0.0
  1527. el = 0.0
  1528. z0 = [0.0, 0.0, 0.0]
  1529. d0 = slicer_plane_int()
  1530.  
  1531. sl.base = WIDGET_BASE(TITLE='IDL Slicer', /ROW)
  1532. ; Setting the managed attribute indicates our intention to put this app
  1533. ; under the control of XMANAGER, and prevents our draw widgets from
  1534. ; becoming candidates for becoming the default window on WSET, -1. XMANAGER
  1535. ; sets this, but doing it here prevents our own WSETs at startup from
  1536. ; having that problem.
  1537. WIDGET_CONTROL, /MANAGED, sl.base
  1538.  
  1539. lbase = WIDGET_BASE(sl.base, /COLUMN)
  1540. if keyword_set(detached) THEN BEGIN
  1541.     rbase = WIDGET_BASE(Title='Slicer', EVENT_PRO='SLICER_EVENT')
  1542.     sl.rbase = rbase
  1543. endif else rbase = WIDGET_BASE(sl.base)
  1544.  
  1545.  
  1546. sl.obuttons = WIDGET_BASE(rbase, /ROW)
  1547. junk = WIDGET_BASE(sl.obuttons, /exclusive, /row)
  1548. junk1 = WIDGET_BUTTON(junk, VALUE='Azimuth', UVALUE='AZIM')
  1549. junk1 = WIDGET_BUTTON(junk, VALUE='Elevation', UVALUE='ELEV')
  1550. WIDGET_CONTROL, junk1, /SET_BUTTON
  1551. junk1 = WIDGET_BUTTON(sl.obuttons, VALUE = 'Go', UVALUE='GOOBL')
  1552. WIDGET_CONTROL, sl.obuttons, MAP=0   ;Remove buttons for oblique mode
  1553.  
  1554. sl.draw = WIDGET_DRAW(rbase, XSIZE=resolution[0], YSIZE=resolution[1],$
  1555.     RETAIN=2, /BUTTON_EVENTS, /MOTION)
  1556.  
  1557. junk = WIDGET_BASE(lbase, COLUMN=3)
  1558. junk1 = WIDGET_BUTTON(junk, value="Done", uvalue = "EXIT", /NO_REL)
  1559. junk1 = WIDGET_BUTTON(junk, value="Erase", uvalue = "ERASE", /NO_REL)
  1560. junk1 = WIDGET_BUTTON(junk, value="Undo", uvalue = "UNDO", /NO_REL)
  1561. junk1 = WIDGET_BUTTON(junk, value="Help", uvalue = "HELP", /NO_REL)
  1562. junk1 = WIDGET_BUTTON(junk, VALUE='Orientation',/MENU)
  1563. ori_names = [ 'X Y Exchange', 'X Z Exchange', 'Y Z Exchange',$
  1564.     'X Reverse','Y Reverse','Z Reverse', 'Reset']
  1565. for i=0,6 do sl.ori_butt[i] = WIDGET_BUTTON(junk1, VALUE=ori_names[i],$
  1566.         UVALUE = 'ORIENTATION')
  1567. widget_control, sl.ori_butt[0], SET_BUTTON=1
  1568.  
  1569. junk1 = WIDGET_BUTTON(junk, VALUE='Interpolation',/MENU)
  1570. junk2 = WIDGET_BUTTON(junk1, VALUE='Off', UVALUE='INTERP0')
  1571. junk3 = WIDGET_BUTTON(junk1, VALUE='On', UVALUE='INTERP1')
  1572. WIDGET_CONTROL, junk3, SENS=0        ;Its on now.
  1573. widget_control, junk1, set_uvalue=[junk2, junk3]
  1574.  
  1575. junk1 = WIDGET_BASE(lbase, /FRAME, COLUMN=3, /EXCLUSIVE)
  1576.  
  1577. for i=0,nmodes-1 do $    ; Mode buttons
  1578.     junk2 = WIDGET_BUTTON(junk1, value=sl.mode_names[i], $
  1579.         uvalue=sl.mode_names[i], /NO_RELEASE)
  1580.  
  1581. junk = WIDGET_BASE(lbase, /FRAME, /COLUMN)
  1582. mode_base = WIDGET_BASE(junk)        ;For the mode dependent bases
  1583.  
  1584. for i=0,nmodes-1 do $
  1585.    if i ne 2 then sl.mode_bases[i] = WIDGET_BASE(mode_base, uvalue=0L, /COLUMN)
  1586.  
  1587.  
  1588. parent = sl.mode_bases[0]        ; slices mode
  1589. junk = WIDGET_DRAW(parent, XSIZE = sl_width, $
  1590.     YSIZE = sl_width * float(resolution[1]) / resolution[0])
  1591. WIDGET_CONTROL, parent, SET_UVALUE= junk
  1592.  
  1593. junk2 = WIDGET_BASE(parent, /ROW)
  1594. junk3 = WIDGET_BASE(junk2, /EXCLUSIVE, /ROW)
  1595. sl.draw_butt[0] = $
  1596.     WIDGET_BUTTON(junk3, VALUE = 'Draw', UVALUE='EXPOSE0', /NO_REL)
  1597. sl.draw_butt[1] = $
  1598.     WIDGET_BUTTON(junk3, VALUE = 'Expose', UVALUE='EXPOSE1', /NO_REL)
  1599. junk3 = WIDGET_BASE(junk2, /EXCLUSIVE, /ROW)
  1600. sl.draw_butt[2] = $
  1601.     WIDGET_BUTTON(junk3, VALUE = 'Orthogonal', UVALUE='ORTHO1', /NO_REL)
  1602. sl.draw_butt[3] = $
  1603.     WIDGET_BUTTON(junk3, VALUE = 'Oblique', UVALUE='ORTHO0', /NO_REL)
  1604.  
  1605. WIDGET_CONTROL, sl.draw_butt[0], /SET_BUTTON
  1606. WIDGET_CONTROL, sl.draw_butt[2], /SET_BUTTON
  1607.  
  1608. parent = sl.mode_bases[1]        ;Cube & Cut modes
  1609. junk = WIDGET_BASE(parent, /ROW)
  1610. junk1 = WIDGET_BUTTON(junk, value=' GO ', uvalue='GOCUBE', /NO_RELEASE)
  1611. junk1 = WIDGET_BUTTON(junk, value=' Cancel ', uvalue='CANCUBE', /NO_REL)
  1612. junk1 = WIDGET_BASE(junk, /EXCLUSIVE, /ROW)
  1613. junk = WIDGET_BUTTON(junk1, VALUE="Cut Into", UVALUE="CUTINTO", /NO_REL)
  1614. junk = WIDGET_BUTTON(junk1, VALUE="Cut Over", UVALUE="CUTOVER", /NO_REL)
  1615. junk = WIDGET_DRAW(parent, XSIZE = sl_width, $
  1616.     YSIZE = sl_width * float(resolution[1]) / resolution[0])
  1617. widget_control, parent, set_uvalue= junk
  1618.  
  1619. sl.mode_bases[2] = sl.mode_bases[1]    ;Cut is copy of cube
  1620.  
  1621. parent = sl.mode_bases[3]          ; Isosurface mode
  1622. junk = widget_button(parent, value='GO', UVALUE='GO')
  1623. junk = widget_base(parent, /row)
  1624. junk1 = widget_label(junk, value='Display: ')
  1625. junk = widget_base(junk, /row, /exclusive)
  1626. junk1 = widget_button(junk, value='High Side', uvalue='HIGH', /NO_REL)
  1627. junk1 = widget_button(junk, value='Low Side', uvalue='LOW', /NO_REL)
  1628. widget_control, junk1, /set_button    ;Set low value
  1629. sl.isop.slider = WIDGET_SLIDER(parent, xsize=sl_width, MINIMUM = 0, $
  1630.         UVALUE = "ISOSLIDE", $
  1631.         TITLE = 'Isosurface Threshold (%)', $
  1632.         MAXIMUM = 100)
  1633. isodraw = WIDGET_DRAW(parent, XSIZE=sl_width, YSIZE = 100, /BUTTON_EVENTS)
  1634.  
  1635. ;    Color tables
  1636. parent = sl.mode_bases[5]
  1637. junk1 = widget_base(parent, /ROW)
  1638. junk = WIDGET_BUTTON(junk1, VALUE = 'Color Tables', /MENU)
  1639. junk2 = 0
  1640. loadct, get_names = junk2
  1641. n = n_elements(junk2) < 24        ;# of buttons to make
  1642. FOR i = 0, n-1 DO sl.color_button[i] = $    ;Make color pull down buttons
  1643.     WIDGET_BUTTON(junk, VALUE=STRTRIM(junk2[i],2), uvalue='COLORS')
  1644.  
  1645. sl.cslide[0] = WIDGET_SLIDER(parent, xsize = sl_width, MINIMUM=0, /DRAG, $
  1646.     MAXIMUM=100, UVALUE = "STMIN", Title="Contrast Minimum", VALUE=0)
  1647. sl.cslide[1] = WIDGET_SLIDER(parent, xsize = sl_width, MINIMUM=0, /DRAG, $
  1648.     MAXIMUM=100, UVALUE = "STMAX", Title="Contrast Maximum", VALUE=100)
  1649. sl.cslide[2] = WIDGET_SLIDER(parent, xsize = sl_width, MINIMUM=0, /DRAG, $
  1650.     MAXIMUM=100, UVALUE = "SHADING", Title="Differential Shading (%)", $
  1651.     VALUE=20)
  1652.  
  1653.  
  1654. parent = sl.mode_bases[6]        ;Rotations mode
  1655. sl.rslide[0] = WIDGET_SLIDER(parent, xsize=sl_width, MINIMUM=-90, MAXIMUM=90, $
  1656.     UVALUE = "XROTATION", Title="X Axis Rotation", VALUE=30)
  1657. sl.rslide[1] = WIDGET_SLIDER(parent, xsize=sl_width, MINIMUM=-179, $
  1658.     MAXIMUM=179, UVALUE = "ZROTATION", Title="Z Axis Rotation", VALUE=30)
  1659. junk = WIDGET_BASE(parent, /frame, /row)
  1660. junk1 = WIDGET_LABEL(junk, VALUE='Z Aspect Ratio:')
  1661. sl.rslide[2] = WIDGET_TEXT(junk, VALUE='1.0     ', /EDIT, YSIZE=1, XSIZE=10)
  1662.  
  1663.  
  1664. parent = sl.mode_bases[7]        ;Journal mode
  1665. junk = WIDGET_BASE(parent, /COLUMN)
  1666. junk1 = WIDGET_BUTTON(junk, VALUE='Start Recording', UVALUE='RECORD', /NO_REL)
  1667. junk1 = WIDGET_BUTTON(junk, VALUE='Stop Recording', UVALUE='RECORDOFF',$
  1668.         /NO_REL)
  1669. junk1 = WIDGET_BUTTON(junk, VALUE='Playback', UVALUE='PLAYBACK', /NO_REL)
  1670. junk = WIDGET_BASE(parent, /ROW)
  1671. junk1 = WIDGET_LABEL(junk, value='File Name:')
  1672. sl.file_text[0] = WIDGET_TEXT(junk, xsize=24, ysize=1, $
  1673.     value='slicer.jou'+string(replicate(32b,14)), /EDIT, /FRAME)
  1674. sl.file_text[1] = WIDGET_TEXT(parent, xsize=32, ysize=1, $
  1675.     value='Journal Closed', /FRAME)
  1676.  
  1677. ;    Transparency buttons / slider
  1678. junk = WIDGET_BASE(lbase, /FRAME, /COLUMN)
  1679. sl.threshold_slider = WIDGET_SLIDER(junk, xsize=sl_width, $
  1680.     MINIMUM=0, MAXIMUM=100,$
  1681.     UVALUE="THRESHOLD", TITLE="Transparency Threshold (%)", VALUE=0)
  1682.  
  1683. junk1 = WIDGET_BASE(lbase, /FRAME)    ;Message base
  1684. sl.pos_text = WIDGET_TEXT(junk1, xsize=40, ysize=1)
  1685.  
  1686. ; Unmap mode dependent widgets  (Leave journal mapped because of obscure bug)
  1687. for i=1, nmodes-1 do widget_control, sl.mode_bases[i], MAP=0
  1688.  
  1689. WIDGET_CONTROL, sl.base, /REALIZE
  1690. if sl.rbase ne 0 then WIDGET_CONTROL, sl.rbase, /REALIZE
  1691. DEVICE, SET_GRAPHICS=3        ;Ensure copy graphics mode
  1692.  
  1693. WIDGET_CONTROL, sl.draw, get_value = junk
  1694. sl.window = junk        ;Main window
  1695. WIDGET_CONTROL, isodraw, get_value = junk
  1696. sl.isop.window = junk        ;Isosurface drawable
  1697. sl.isop.drawable = isodraw
  1698.  
  1699. sl.nc1 = (!d.n_colors < 256) -1 ;Colors we can use
  1700. sl.nc3 = (sl.nc1-3)/3        ;Colors per orientation
  1701.  
  1702. slicer_orientation,6        ;Reset to default orientation, erase
  1703. slicer_colors, 0
  1704.  
  1705. if n_elements(commands) gt 0 then slicer_playback, commands  ;Execute cmds?
  1706. if n_elements(cmd_file) gt 0 then slicer_playback, file = cmd_file
  1707.  
  1708. device,    TRANSLATION = tbl    ;Read hdw translation table
  1709.                 ;Distance between white and black
  1710. if !d.name eq 'X' then sl.xcol = tbl[0] xor tbl[sl.nc1]  $
  1711. else sl.xcol = 196        ;Windows.
  1712.  
  1713. tbl=0                ;Kill it
  1714. WSET, swin
  1715. XManager, "slicer", sl.base, EVENT_HANDLER = slicer_events, GROUP = group, $
  1716. /NO_BLOCK, MODAL=KEYWORD_SET(modal)
  1717. end
  1718.